Create a CDS view (ABAP)

1. In the context menu of your package choose New and then choose Other ABAP Repository Object.
   

2. Select Data Definition, then choose Next.
   

3. Enter the following values, then choose Next:

   • Name = Z_INVOICE_ITEMS
   • Description = Invoice Items
     

4. Accept the default transport request (local) by simply choosing Next again.
   

5. Select the entry Define View, then choose Finish
   

The new view appears in an editor. In this editor, enter the following values:

1. Enter ZINVOICEITEMS as the SQL view name.
2. Enter the CDS view sepm_sddl_so_invoice_item as the data source for your view.
3. Use code completion (keyboard shortcut CTRL+SPACE) to get proposals for the data source.
   

Note: The SQL view name is the internal/technical name of the view which will be created in the database. Z_Invoice_Items is the name of the CDS view which provides enhanced view-building capabilities in ABAP. You should always use the CDS view name in your ABAP applications.

You will now insert the fields currency_code and gross_amount into the SELECT list as follows:

1. Trigger code completion in the SELECT list (by clicking on the SELECT list and using keyboard shortcut CTRL+SPACE), then double click on the entry Insert all elements - template. All the elements (fields and associations) of the underlying data source are inserted into the SELECT list.
2. Remove all the elements in the SELECT list which were inserted by the code completion apart from currency_code and gross_amount. Remember to separate the elements in the SELECT statement with a comma.
   
   

You will now model the relationships between data sources by using some existing CDS associations. You can use associations in path expressions to access elements (fields and associations) in related data sources without specifying JOIN conditions. You can now display the element info by positioning the cursor on the data source name sepm_sddl_so_invoice_item and choosing F2.

To see the related data sources that can be accessed using associations, scroll down.
To see details about the target data source of the association header, choose the hyperlink sepm_sddl_so_invoice_header.

You will now add fields of related data sources to the SELECT list of Z_Invoice_Items, using the associations in path expressions. Each element in the path expression must be separated by a period.

1. Add the company_name of the business partner to the SELECT list using the associations header and buyer in a path expression
2. You will get an error, “Field header must be included in the selection list together with field SEPM_SDDL_SO_INVOICE_ITEM.SALES_ORDER_INVOICE_KEY”. Resolve this by adding the field sepm_sddl_so_invoice_item.sales_order_invoice_key to the Select statement.
3. Add the payment_status from the invoice header to the SELECT list using the association header
   

If the invoice has been paid, you want to set the payment_status to X (true). Do this by implementing a CASE statement

case header.payment_status
    when 'P' then 'X'
    else ' '
end as payment_status

You will now filter the results so that only invoice items with currency_code = 'EUR' are retrieved.

1. Add a WHERE clause:

   WHERE currency_code = 'EUR'
   

   

2. Save and activate the data definition by choosing Save (Ctrl+S) and Activate (Ctrl+F3).
   

Your CDS view should look like this:

@AbapCatalog.sqlViewName: 'ZINVOICEITEMS2'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'CDS View for "Use-cds-view" tutorial'
define view Z_Invoice_Items_2
  as select from sepm_sddl_so_invoice_item
{
  //sepm_sddl_so_invoice_item

  header.buyer.company_name,
  sepm_sddl_so_invoice_item.sales_order_invoice_key,
  sepm_sddl_so_invoice_item.currency_code,
  sepm_sddl_so_invoice_item.gross_amount,

  case header.payment_status
  when 'P' then 'X'
  else ' '
  end

  as payment_status,

//* Associations *//
  header
}

where currency_code = 'EUR'

Open the CDS View in the Data Preview by choosing F8. Your CDS View should look like this: